AccueilVersion Calc 1.x Version Calc 2.x Présentation Calc 3.xBien débuter Calc Fonctions Calc Exercices Calc FormulairesAstuces CalcPrécisions calculsLa bonne formuleProgrammation BasicLiens diversDéfinitionsRecherche sur siteHumourInfos, news

FONCTIONS CALC. Fonctions Dates et heures

 




Accès direct : Menu fonctions, texte, dates et heures, logiques, mathématiques, base de donnèes, financières, add-in, statistiques 1, statistiques 2, matrice, classeur, informations, OPERATION.MULTIPLE,

 

NOTA Les syntaxes des fonctions sont notées de cette manière (exemple) : =FONCTION(argument obligatoire 1; argument obligatoire 2 ; argument en option 3; argument en option 4)
Sauf cas particuliers, les paramètres optionnels peuvent être ignorés s'ils ne sont pas suivis d'autres paramètres. Par exemple, on peut ignorer les arguments 3 et 4 mais pas l'argument 3 si on utilise l'argument 4.

Plusieurs exemples sont basés sur les dates et heures réelles de votre système au moment du chargement de la page. Rechargez cette page pour modifier le temps.

Fonctions Syntaxe Exemples Résultats Commentaires
ANNEE
YEAR
=ANNEE (date entière) =ANNEE (A1) 2014 (si A1 contient 01/09/2014 ou 01/09/14) Retourne l'année d'une date au format date ou au format numérique. § MOIS, JOUR, AUJOURDHUI, JOURSEM
=ANNEE(41883) 2014 (41883 correspond au 01/09/2014)
=ANNEE("2014-9-1") 2014
=ANNEE (AUJOURDHUI()) 2014
ANNEES
YEARS
=ANNEES (date entière; date entière; mode) =ANNEES(A1; A2; 0) 2 (si A1 contient 01/01/2004 et A2 01/01/2006) Ecart en années entre 2 dates. mode 0 ou 1 (détermine le mode de calcul de la différence).
Pour les calculs d'âges, écarts entre dates, voir Exemples formules ou via une fonction additionnelle DATE_DIF
=ANNEES(A1; A2; 0) 1 (si A1 contient 28/02/2004 et A2 27/02/2006)
=ANNEES(A1; A2; 1) 2 (si A1 contient 28/02/2004 et A2 27/02/2006)
=ANNEES("2004-01-01"; "2006-01-01"; 0) 2
AUJOURDHUI
TODAY
=AUJOURDHUI() =AUJOURDHUI() 01/09/2014 Retourne la date de l'ordinateur. § MAINTENANT, DATE, JOUR
DATE
DATE
=DATE (année; mois; jour) =DATE (2014; 09; 01) 01 sept. 2014 (suivant format affichage) Retourne une date. Année variable de 1583 à 9956 ou entre 0 et 99. On régle les numéros à 2 chiffres sous Outils, Options, OpenOffice.org ou LibreOffice, Général.
§ DATEVAL, TEMPSVAL, ANNEE, MOIS, JOUR
DATEVAL
DATEVALUE
=DATEVAL (date entière) =DATEVAL ("01/9/14") 41883 Formatez pour afficher correctement la date. Si le texte n'est pas une date, message d'erreur. 1er exemple pour anciennes versions OOo. § DATE, TEMPSVAL, AUJOURDHUI
=DATEVAL ("01 sept. 2014")
=DATEVAL("2010-08-24")
DIMANCHEDEPAQUES
EASTERSUNDAY
=DIMANCHEDEPAQUES (année) =DIMANCHEDEPAQUES (2004) 11/04/04 Retourne la date du dimanche de Pâques. Sert de référence pour toutes les fêtes mobiles. Années possibles entre 1583 et 9956 ou entre 0 et 99 suivant réglage années à 2 chiffres.
=DIMANCHEDEPAQUES (2014) 20/04/2014
ESTBISSEXTILE
ISLEAPYEAR
=ESTBISSEXTILE() =ESTBISSEXTILE ("2004-02-05") 1 Retourne 1 (VRAI) si année bissextile, 0 (FAUX) si non bissextile. Ne pas utiliser ESTBISSEXTILE (29-02-année). § JOURSDANSANNEE .
=ESTBISSEXTILE (A1) 1 (Si A1 contient 5/2/04)
=ESTBISSEXTILE ("2014-9-1") 0
FIN.MOIS
EOMONTH
=FIN.MOIS (date initiale; mois) =FIN.MOIS (A1; 0) 30/09/2014 (si A1 contient 01/9/14) Retourne la date du dernier jour d'un mois. Formater pour afficher correctement la date.
date initiale : date de départ du calcul
mois : décalage positif ou négatif. valeur zéro pour la fin du mois de date initiale
=FIN.MOIS A1; -1) 31/08/2014 (si A1 contient 01/9/14)
=FIN.MOIS (A1; 1) 31/10/2014 (si A1 contient 01/9/14)
=FIN.MOIS ("2014-9-1"; 0) 30/09/2014
=FIN.MOIS ("2014-9-1"; -1) 31/08/2014
=FIN.MOIS ("2014-9-1"; 1) 31/10/2014
FRACTION.ANNEE
YEARFRAC
=FRACTION.ANNEE (date début; date fin; base) =FRACTION.ANNEE (A1; A2; 0) 0,67 (suivant format affichage et si A1 contient 5/2/04 et A2 5/10/04) Valeur numérique. Utilisé pour les calculs comptables de 12 mois de 30 jours. Mode=0, pour méthode américaine, ou base=1, pour méthode européenne (Anciennes versions OOo).
date début, date fin : dates entières
Base :
0 ou vide:
Méthode américaine (NASD), 12 mois à 30 jours chaque
1 : Nombre exact de jours dans le mois, nombre exact de jours dans l'année
2 : Nombre exact de jours dans le mois, année à 360 jours
3 : Nombre exact de jours dans le mois, année à 365 jours
4 : Méthode européenne, 12 mois à 30 jours chaque  
=FRACTION.ANNEE ("2004-02-05"; "2004-10-05"; 0) 0,67
HEURE
HOUR
=HEURE(heure entière ou décimale) =HEURE ("22:56:38") 22 Retourne une heure. § MINUTE, SECONDE
=HEURE (0.95599537037037)
JOUR
DAY
=JOUR (date entière) =JOUR(41883) 1 Retourne le jour d'une date donnée. § JOURS, JOURS360, JOURSDANSANNEE, JOURSDANSMOIS, JOURSEM
=JOUR("2014-9-1")
=JOUR (AUJOURDHUI())
JOURS
DAYS
=JOURS (date entière; date entière) =JOURS (AUJOURDHUI(); "2008-2-28") 2377 Retourne le nombre de jours entre 2 dates. § JOUR, NB.MOIS
=JOURS ("2010-9-1"; "2008-2-28") 916
JOURS360
DAYS360
=JOURS360 (date entière; date entière; mode) =JOURS360 ("2004-02-05"; "2005-02-05"; 0) 360 Différence entre 2 dates d'une année de 360 jours. Utilisé pour les calculs comptables de 12 mois de 30 jours. Mode=0 ou facultatif, pour méthode américaine, ou Mode=1, pour méthode européenne. § JOUR
JOURSDANSANNEE
DAYSINYEAR
=JOURSDANSANNEE (date entière) =JOURSDANSANNEE ("2014-9-1") 365 Retourne le nombre de jours de l'année. Identique à =ESTBISSEXTILE (date) +365. § ESTBISSEXTILE, JOUR
=JOURSDANSANNEE(41883)
JOURSDANSMOIS
DAYSINMONTH
=JOURSDANSMOIS (date entière) =JOURSDANSMOIS ("2014-9-1") 30 Retourne le nombre de jours du mois de la date citée.
=JOURSDANSMOIS (41883)
JOURSEM
WEEKDAY
=JOURSEM (date entière; type) =JOURSEM (2004-02-05")

5

Donne le n° du jour de la semaine. Résultat suivant type :
  • 1 ou omis : du dimanche (1) au samedi (7).
  • 2 : du lundi (1) au dimanche (7)
  • 3 : du lundi (0) au dimanche (6).
=JOURSEM (A1) 1 (si A1 contient 01/09/2014 ou 01/09/14)
=JOURSEM ("2014-9-1"; 2) 1 (lundi)
=JOURSEM(41883; 2)
MAINTENANT
NOW
=MAINTENANT() =MAINTENANT() 01/09/2014 22:56 A comparer avec AUJOURDHUI. Réactualisation (heure) par touche F9.
MINUTE
MINUTE
=MINUTE (heure entière ou décimale) =MINUTE ("22:56:38") 56 Retourne les minutes. § HEURE, SECONDE
=MINUTE (0.95599537037037)
=MINUTE (MAINTENANT())
MOIS
MONTH
=MOIS (date entière) =MOIS ("2014-9-1") 9 Retourne le mois. § ANNEE, JOUR
=MOIS(41883)
=MOIS (AUJOURDHUI())
MOIS.DECALER
EDATE
=MOIS.DECALER (date entière; décalage en mois) =MOIS.DECALER ("2004-02-05"; 5) 38173 ou 05/07/2004 suivant format Retourne une date décalée de n mois (positif ou négatif). Les jours ne sont pas pris en compte.
=MOIS.DECALER (38022; 5)
=MOIS.DECALER ("2006-07-31"; -1) 30/06/2006 suivant format
NB.JOURS.OUVRES
NETWORKDAYS
=NB.JOURS.OUVRES (date début; date fin; congés et fêtes) Voir détails et exemples à la suite de ce tableau Retourne le nombre de jours en tenant compte des jours chômés et des congés éventuels. § SERIE.JOUR.OUVRE
NB.MOIS
MONTHS
=NB.MOIS (date début; date fin; mode) Voir exemples à la suite de ce tableau Retourne le nombre de mois d'une période donnée. Mode 0 ou 1:
  • 0: nombre de mois dans l'intervalle.
  • 1: mois du calendrier.
NO.SEMAINE
WEEKNUM
=NO.SEMAINE (date entière; mode) Voir exemples à la suite de ce tableau retourne le numéro de semaine. Mode 1 pour semaine débutant le dimanche et 2 pour débutant le lundi
NO.SEMAINE_ADD
WEEKNUM_ADD
=NO.SEMAINE_ADD (date entière; mode)
SECONDE
SECOND
=SECONDE (heure entière ou décimale) =SECONDE ("22:56:38") 38 Retourne les secondes. § HEURE, MINUTE
=SECONDE (0.95599537037037)
SEMAINES
WEEKS
=SEMAINES (date entière; date entière; mode) =SEMAINES ("2003-9-1"; "2004-2-5"; 0) 22 Ecart en semaines entre 2 dates. mode 0 (intervalle) ou 1 (nombre de semaines)
SEMAINESDANSANNEE
WEEKSINYEAR
=SEMAINESDANSANNEE (date entière) =SEMAINESDANSANNEE ("2004-02-05") 53 Retourne le nombre de semaines dans l'année. Une semaine chevauchant deux années est comptée dans l'année contenant la majorité des jours de cette semaine. La valeur doit être une vraie date (pas uniquement l'année).
SERIE.JOUR.OUVRE
WORKDAY
=SERIE.JOUR.OUVRE (date début ;jours; congés et fêtes) Voir détails et exemples à la suite de ce tableau Retourne une date tenant compte des jours chômés et des congés éventuels.
date_début : date de début calcul. Si la date de début est un jour ouvré, le jour est inclus dans le calcul.
jours : nombre de jours ouvrés (positif ou négatif).
fériés : liste de jours fériés facultatifs.
§ NB.JOURS.OUVRES
TEMPS
TIME
=TEMPS (heures; minutes; secondes) =TEMPS (22; 56; 38) 22:56:38 suivant affichage Retourne une valeur horaire à partir des valeurs : heures, minutes, secondes. Si formatage nombre, retourne l'équivalent de TEMPSVAL
TEMPSVAL
TIMEVALUE
=TEMPSVAL (heures; minutes; secondes) =TEMPSVAL ("22:56:38") 0.95599537037037 suivant affichage Retourne l'heure en format numérique. Varie de 0 (0 heure) à 1 (24 h).

 

Remarque Les fonctions AUJOURDHUI() et MAINTENANT() donneront toutes les 2 la date du jour. La seconde fournira en plus l'heure actuelle (de votre système).

Important La version OOo 3.2 a apporté des changements pour être en conformité avec la norme ISO 8601. Plusieurs fonctions qui acceptaient les paramètres dates entre guillemets avec barre de division (/), comme par exemple =JOUR ("01/9/14"), retourne désormais #VALEUR! Il faut donc inscrire les dates dans une autre cellule, comme par exemple = JOUR(A1) si A1 contient la date, 01/09/2014, et retournera 1, ou lire sa valeur numérique, =JOUR(41883), (valeur numérique de 01/09/2014).
Autre possibilité, utiliser la norme ISO 8601 en écrivant (par exemple) =JOUR("2014-9-1")

 

 

Les formats dates

 

1/9/2014
01/09/2014
1 septembre 2014
 lundi 01 septembre 2014 

Entrer une date

  Pour entrer une date dans une cellule, la méthode la plus naturelle est d'écrire au format jour/mois/année. Par exemple, nous entrons la date du 5 février 2004 ou 05/02/2004 ou 5/2/04. Voici quelques méthodes ci-contre, du plus simple au plus compliqué !

A partir d'une date, il est possible d'obtenir de multiples affichages. Voici quelques exemples de format (les formats anglo-saxons ne sont pas présentés).

Date entrée Format Affichage obtenu
1  01 septembre 2014  JJ/MM/AAAA   01/09/2014
2 01 septembre 2014 JJ-MM-AAAA 01-09-2014
3 01 septembre 2014  NNNNJ MMMM AAAA  lundi 01 septembre 2014
4 01 septembre 2014 JJJJ JJ MMMM AAAA  lundi 01 septembre 2014 
5 01 septembre 2014 JJ/MM/AA 01/09/14
6 01 septembre 2014 J MMM AA 1 sept. 14
7 01 septembre 2014 J MMM AAAA 1 sept. 2014
8 01 septembre 2014 J MMMM AAAA 1 septembre 2014
9 01 septembre 2014 NN J MMM AA lun. 1 sept. 14
10 01 septembre 2014 JJJ J MMM AA lun. 1 sept. 14
11 01 septembre 2014 J 1
12 01 septembre 2014 JJ 01
13 01 septembre 2014 JJJ lun.
14 01 septembre 2014 NN lun.
15 01 septembre 2014 JJJJ lundi
16 01 septembre 2014 NNN lundi
17 01 septembre 2014 M 9
18 01 septembre 2014 MM 09
19 01 septembre 2014 MMM sept.
20 01 septembre 2014 MMMM septembre
21 01 septembre 2014 AA ou E 14
22 01 septembre 2014 AAAA ou EE 2014
23 01 septembre 2014 Q T3
24 01 septembre 2014 QQ AA 3e trimestre 14
25 01 septembre 2014 QQ AAAA 3e trimestre 2014
26 01 septembre 2014 AAAA G 2014 apr. J.-C.
27 01 septembre 2014 R 2014
28 01 septembre 2014 RR ap. J.-C.2014
29 01 septembre 2014 WW 36
30 01 septembre 2014   41883

Beaucoup de formats dates existent déjà. Certains sont redondants (3 et 4, 9 et 10, 13 et 14, 15 et 16).

A partir d'une date entière il est possible de n'afficher qu'une partie : jours (11 à 16), mois (17à 20), année (21 et 22), trimestre (23 à 25), numéro de semaine (29).

En 30, notez l'affichage curieux (41883). La cellule a été formatée au format nombre (sans décimale). Ce nombre représente le nombre de jours écoulés depuis la date de référence définie dans : Outils, Options, Boite de dialogue Options - Classeur - Calcul, Classeur, Calcul, Date :
30.12.1899 (par défaut)
01.01.1900 (Star Calc 1.0)
01.01.1904 (autre tableur)

Si vous modifiez cette option alors que votre classeur contient des dates, toutes les dates seront modifiées. Il convient donc d'être prudent.

Information la date référence (par défaut) dans Calc est le 30/12/1899, ce qui laisse supposer qu'il est impossible d'utiliser les dates antérieures, ce qui est faux.
Pour corriger une erreur de 10 jours, le pape Grégoire XIII a proposé le calendrier grégorien, et il a été décidé que le lendemain du 4 octobre 1582 serait 15 octobre 1582. Calc tient compte de cet évenement. On peut faire le test en écrivant dans une cellule la date du 1 octobre 1582, puis en recopiant vers le bas : le lendemain du 04/10/1582 sera bien le 15/10/1582. Il est théoriquement possible de créer un calendrier depuis le 01 janvier de l'an 100.

Il est possible d'écrire suivant la norme ISO, avec AAAA (année sur 4 chiffres), MM (mois sur 1 ou 2 chiffres), JJ (jour sur 1 ou 2 chiffres), soit AAAA-MM-JJ. Sauf modification particulière, le tableur transformera automatiquement en JJ/MM/AA. De même il est possible d'écrire JJ-MM-AAAA. La transformation se fera naturellement. Toutefois, pour éviter les erreurs, il est souhaitable d'entrer les années ISO sur 4 chiffres.

Exemple : 25 août 2010. Si écrit 2010-08-25, traduction normale 25/08/10, mais si écrit 10-08-25, sera traduit 10/08/25 (mais 2025 !).

 

 

 

 

 

Effets indésirables. Si vous écrivez 1.4 (pas 1,4), le tableur interprête le 01/04/année en cours. Si vous écrivez février 2004, le tableur interprétera en date et affichera par exemple 01/02/2004, suivant format. Si vous voulez que votre date, février 2004, reste un texte, il faudra, avant d'entrer ce texte, formater la cellule au format texte via clic droit, dans le menu flottant Formatage des cellules, onglet nombres, Catégorie, Texte. Autre possibilité : écrire une apostrophe avant d'entrer la date.

Autres cas d'indésirables : écrivez 1/3 et vous obtiendrez 01/03/année en cours. Vous pouvez contourner en écrivant =1/3. Le même genre d'erreur arrive avec 1/2 et 1/4 si vous avez décoché l'Autocorrection (Outils, Autocorrection, Options)

 

Entrée heure

 

On peut entrer au format heures : minutes : secondes.

Si on entre 2 valeurs séparées des 2 points (:), le tableur interprète heures et minutes.

Si on entre 3 valeurs séparées des 2 points, le tableur interprète heures, minutes et secondes.

On peut ajouter des dixièmes, centièmes, millièmes,.. en entrant une virgule à la suite des heures, minutes et secondes.

Attention. Si vous entrez 1h 12mn et 25 centièmes, il faut entrer : 1:12:00,25 et non 1:12,25. Dans ce dernier cas le tableur interprète 1 minute 12 secondes et 25 centièmes.

Pour éviter les effets indésirables, comme l'affichage d'un texte ressemblant à une heure, même méthode que celle décrite pour les dates.

Heure entrée Format Affichage obtenu
1 01:02:03,456 HH:MM:SS 01:02:03
2 01:02:03,456 [HH]:MM:SS 01:02:03
3 01:02:03,456 HH:MM 01:02
4 01:02:03,456 HH 01
5 01:02:03,456 H 1
6 01:02:03,456 HH:MM AM/PM 01:02 am
7 01:02:03,456 HH:MM:SS AM/PM 01:02:03 am
8 01:02:03,456 HH:MM:SS,00 01:02:03,46
9 01:02:03,456 HH:MM:SS,000 01:02:03,456
10 01:02:03,456 MM:SS 02:03
11 01:02:03,456 [MM]:SS 62:03
12 01:02:03,456 SS 03
13 01:02:03,456 [SS] 3723
14 34:56:12 HH:MM:SS 10:56:12
15 34:56:12 [HH]:MM:SS 34:56:12
16 01:23:45 H\h MM\mn SS\s 1h 23mn 45s

Pour notre exemple, en ligne 1, une heure avec des millièmes. Le principe est le même que pour les dates. Le séparateur est maintenant les 2 points (:).

Notez qu'on ne peut afficher que les heures, les minutes ou les secondes.

Notez des différences importantes, n°10 et 11. En ligne 11, est affiché le total des minutes. Le même principe est appliqué au n° 13, où on affiche le nombre total de secondes.

En ligne 15, on affiche une heure supérieure à 24 heures.

En ligne 16, on fabrique un affichage personnalisé. Après les formats heures (H), minutes (MM) et secondes (SS), on applique une barre inverse (\) suivie du texte voulu.

Dans la même cellule on peut écrire une date et une heure. Par exemple si vous entrez : 05/02/04 4:21, le tableur interprétera bien (et affichera en fonction des formats) jeudi 5 février 2004, 04h 21mn

 

 

 

Attention au piège

Réalisons une opération simple, ici une soustraction. Les formats heures appliqués sont HH:MM:SS.

Le résultat est pour le moins étonnant et apparemment faux. En fait le tableur interprète 24 heures moins 2 heures, donc 22 heures.

Mais il s'agit bien de valeur négative (2 heures avant les 24 heures). En modifiant le format d'affichage [HH]:MM:SS, tout devient correct.

 

Attention au piège (2)

Le calcul d'âge (année, mois, jour) est une source fréquente d'erreur. On a tendance à soustraire la date actuelle à la date de naissance, puis si nécessaire d'afficher au format Jour / Mois / Année. Cette méthode n'est que très approximative et fausse. Démonstration. Une personne est née le 25 janvier 1930 (soit la valeur numérique 10983). Si nous sommes le 15 septembre 2010 (soit la valeur numérique 40436). Avec une simple soustraction, nous obtenons 80 ans 8 mois et 20 jours. En fait nous appliquons une valeur numérique (résultat de soustraction), 29453 dans ce cas précis, qui correspond à la date du 20/08/1980.

Pour avoir un résultat précis, il faut employer une formule (si la date de naissance est en A1): =(ANNEES(A1; MAINTENANT();0)) & " ans " & (NB.MOIS(A1; MAINTENANT();0) - (ANNEES(A1; MAINTENANT(); 0))*12) & " mois " & (SI(JOUR(MAINTENANT()) - JOUR(A1) >=0; JOUR(MAINTENANT()) - JOUR(A1); JOUR(MAINTENANT()) + (JOURSDANSMOIS(MOIS.DECALER (MAINTENANT(); -1)) - JOUR(A1)))) & " jours"

Cette fois-ci, nous avons le bon résultat : 80 ans 7 mois 21 jours. Pas très simple, mais efficace. Il existe d'autres formules. Voir dans les astuces.

 

 

 

Exemples NO.SEMAINE et NO.SEMAINE_ADD

 

 

Ci-contre un tabeau récapitulatif des fonctions comparables NO.SEMAINE et NO.SEMAINE_ADD en mode 1 (la semaine commence le dimanche) et 2 (la semaine commence le lundi). Surlignée en jaune les cases dont la valeur change.

Une différence essentielle est que dans NO.SEMAINE_ADD, le numéro repart à 1 au 1er janvier, quelque soit le jour de la semaine, contrairement à NO.SEMAINE. Ceci explique les différences plus ou moins un qui peuvent se produire entre les 2 formules.

La norme internationale ISO 8601 défini le lundi comme premier jour de la semaine.

 

 

Exemples NB.MOIS

 

 

Pour illustrer cette fonction, regardez le tableau ci-contre. Plusieurs dates et les résultats en fonction du mode 0 ou 1.

 

 

 

 

Exemples NB.JOURS.OUVRES

 

 

Pour illustrer cette fonction, regardez le tableau ci-contre. On entre une date de début en A2, une date de fin en B2, une liste éventuelle de congés en C2:C8.

Si vous recopiez ce tableau, faites attention aux formatages de dates.

Exemple simple, du lundi au mardi, 2 jours ouvrés.

Pour comprendre l'évolution, une date de début fixe, et une date fin évolutive. Regardez les nombres de jours ouvrés qui ne changent pas les samedi et dimanche. Ils ne comptent pas comme jours ouvrés.

Test avec des jours de congés.

Ajoutez un dimanche dans les congés, il ne sera pas pris en compte.

 

 

 

Exemples SERIE.JOUR.OUVRE

 

 

Pour illustrer cette fonction, regardez le tableau ci-contre. On entre une date de début en A2, un nombre de jours en B2, une liste éventuelle de congés en C2:C8.

Si vous recopiez ce tableau, faites attention aux formatages de dates.

Aucun jour de congé, un jour d'activité, donc en passe à la date du lendemain.

Autre variante avec 4 jours d'activité.

Inscrivons des congés, ils sont bien pris en compte.

Enfin, pour bien comprendre cette fonction, à partir d'une même date et d'un nombre de jours de 1 à 7, regardez l'évolution. On passe du vendredi au lundi. Les samedi et dimanche sont considérés comme chômés.

 

 



Principales fêtes fixes et mobiles.

    

Tableau pour la France. Contactez-moi en cas d'erreur ou pour le compléter.

Nom Férié Jour Mois Décalages, infos
Jour de l'an oui 1 1  
Epiphanie non 6 1  
Chandeleur non 2 2  
Fête du travail oui 1 5  
Victoire 1945 oui 8 5  
Fête nationale oui 14 7  
Assomption oui 15 8  
Toussaint oui 1 11  
Armistice 1918 oui 11 11  
Noël oui 25 12  
         
Mardi Gras non     -47 (décalage Pâques)
Cendres non     -46 (décalage Pâques)
Carême non     -42 (décalage Pâques)
Rameaux non     -07 (décalage Pâques)
Vendredi saint variable     -02 (décalage Pâques)
Pâques oui      
Lundi de Pâques oui     +01 (décalage Pâques)
Ascension oui     +39 (décalage Pâques)
Pentecôte oui     +49 (décalage Pâques)
Lundi de Pentecôte variable     +50 (décalage Pâques)
Trinité non     +56 (décalage Pâques)
Fête-Dieu non     +60 (décalage Pâques)
Sacré-Coeur non     +68 (décalage Pâques)
         
Printemps non 20 03  
Eté non 21 06  
Automne non 23 09  
Hiver non 22 12  
         
Heure d'été non     Dernier dimanche de mars
Heure d'hiver non     Dernier dimanche d'octobre
         
Fêtes des mères non     Dernier dimanche de mai
Fêtes des pères non     3ème dimanche de juin
         




Pour aller plus loin

  


Pour comprendre les structures des dates et heures dans Calc, regardez l'exemple suivant:

Les colonnes A, B et C ne contiennent rien d'autres que les mêmes valeurs de la colonne A. La différence est qu'en B on applique le format date et en colonne C le format heure . La première date correspond au réglage par défaut Outils, Options, Classeur, Calcul, Date 30.12.1899 par défaut.

Entre les valeurs 0 et 1, il s'écoule 24 heures, donc un jour.

Pour entrer un peu plus dans les détails, en colonne E, sont inscrites des heures entières (de 2h en 2h) et en colonne F, la valeur numérique correspondante. Les exemples sont limpides:

  • 6 heures = 0,25 soit le un quart de 24 heures
  • 8 heures = 0,33 soit le tiers de 24 heures
  • 12 heures = 0,50 soit la moitié de 24 heures

etc...

Ces exemples vous permettent également de comprendre pourquoi on peut mélanger des heures et des valeurs (comme des montants par exemple) dans les calculs.

 

Allons plus loin dans nos exemples en mixant date et heure, comme sur cet exemple la valeur 9,75 que nous traduisons en date et heure et qui affichera 08/01/1900 à 18h00. Ceci correspond bien à la valeur 9 (ligne 11) pour la date et à la valeur 0,75 pour l'heure.

En suivant ces exemples, on peut calculer facilement des heures de nuit. Supposons un horaire de 10 heures du soir (22 heures) à 4 heures 30 du matin. 22:00 - 4:30 retournera 17:30. Pour obtenir un résultat correct, il faut décompter de 22 heures à minuit. Donc 24:00 - 22:00. Si vous écrivez littéralement =24:00 - 22:00, vous obtiendrez 0,08 (soit 2 heures). Il est également correct d'écrire =1 - 22:00, même si cela semble curieux. Regardez comment la formule est traduite dans la barre de calculs. Vous lisez : =1-0,916666666666667. C'est correct !

Pour finir, on peut donc écrire = 1-22:00 + 4:30 le résultat est 0,27 soit 6 heures 30
Il est également possible d'écrire = 4:30 - 22:00 + 1 pour un résultat identique.

 

 



 


 

Ce site n'est plus mis à jour. Merci aux nombreux visiteurs depuis 2003. Consultez le Wiki LibreOffice.
   

Le tableur Calc par l'exemple : christianwtd@free.fr
Creative Commons License
This work is licensed under a Creative Commons Attribution-NonCommercial-ShareAlike 2.0 France License.

  .

Site optimisé pour Firefox

Dernière modification : 05/03/2012 à 21h10


Compteur de visite temps réel LERAPIDE

Compteur non certifié